A long time starting FrameMaker

[Klaus Mueller]

Hello Rick,

A co-worker of mine once had the same problem:
On her system, there was a font installed from the network,
without copying it to the fonts folder.
And in the meantime, the font was removed ...

>> Is there someone I can go to check the path
>> of where Frame is looking for fonts.

Your client should take a look into the registry:
- HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts
- HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\
  Type 1 Installer\Type 1 Fonts

Alternatively, she could run the following FrameScript script.
It reports all installed fonts with folder and filename
(FrameScript 3.0 or later required).

Kind regards,
Klaus


8< -------------------------------------------------

  //-- ReportInstalledFonts.fsl v0.3
  //-- mailto:klaus.mueller at itl.eu
  Set PlatformEncodingMode = True;
  Set lvTTKey = 'Software\Microsoft\Windows NT\CurrentVersion\Fonts';
  Set lvT1Key = 'Software\Microsoft\Windows NT\CurrentVersion\'+
    'Type 1 Installer\Type 1 Fonts';
  Set lvFoldersKey = 'Software\Microsoft\Windows\CurrentVersion\'+
    'Explorer\Shell Folders';
  Run ESys.GetAllRegistryKeyValueNames Group('LocalMachine')
    Key(lvTTKey) NewVar(lvTTFontLst);
  Run ESys.GetAllRegistryKeyValueNames Group('LocalMachine')
    Key(lvT1Key) NewVar(lvT1FontLst);
  Run ESys.GetRegistryKeyValue Group('CurrentUser') Key(lvFoldersKey)
    ValueName('Fonts') NewVar(gvFontFolder);
  Sort List(lvTTFontLst);
  Sort List(lvT1FontLst);
  Set gvData = 'Name' +CharLF+ 'File' + CharLF+ 'Folder' + CharLF;
  Run ReportFontList pvFontList(lvTTFontLst) pvKey(lvTTKey);
  Run ReportFontList pvFontList(lvT1FontLst) pvKey(lvT1Key);

  New Document NewVar(lvTxtDoc) Portrait Invisible;
  Set lvPgf = lvTxtDoc.MainFlowInDoc;
  New Text Object(lvPgf) gvData;
  Set lvTmpFile = TmpDir+DirSep+'~FRM.tmp';
  Save Document DocObject(lvTxtDoc) File(lvTmpFile)
    FileType(SaveFmtText);
  Close Doc DocObject(lvTxtDoc) IgnoreMods;
  New Document NewVar(lvDoc) Portrait ViewTextSymbols(False)
    ViewRulers(False) ViewBorders(False);
  Import File File(lvTmpFile) TextLoc(lvDoc.MainFlowInDoc)
    HowToImport(DoByCopy) FilterFormatId('TEXT')
    FileIsText(DoImportAsTable)
    ImportTblTag(lvDoc.FirstTblFmtInDoc.TblTag) TreatParaAsRow(False)
    LeaveHeadingRowsEmpty(False) TblNumHeadingRows(1) NumColumns(3);
  Delete File(lvTmpFile);
  New MetricList NewVar(lvTblColWidths) Value(2") Value(1.5") Value(3");
  Loop ForEach(Tbl) In(lvDoc) LoopVar(lvTbl)
    If (lvTbl.Page.ObjectName = 'BodyPage')
      Set lvTbl.TblTitlePosition = TblNoTitle;
      Set lvTbl.TblColWidths = lvTblColWidths;
    EndIf
  EndLoop
  Set lvCount = lvTTFontLst.Count + lvT1FontLst.Count;
  New Text Object(lvDoc.FirstPgfInMainFlow) lvCount +
    ' fonts installed.';
  Save Document DocObject(lvDoc) File(TmpDir+DirSep+'FontList.fm');
  Execute FC KbdWindowFullUp;

  Sub ReportFontList pvFontList pvKey
  Loop While(lvCounter <= pvFontList.Count) LoopVar(lvCounter)
    InitVal(1) Incr(1)
    Set lvRow = lvRow.NextRowInTbl;
    Set lvCell = lvRow.FirstCellInRow;
    Get Member Number(lvCounter) From(pvFontList) NewVar(lvFontName);
    Set lvFontFile = '';
    Run ESys.GetRegistryKeyValue Group('LocalMachine') Key(pvKey)
      ValueName(lvFontName) NewVar(lvFontFile);
    If (lvFontFile.ObjectName = 'Strings')
      Set lvFontFile = lvFontFile[3];
    EndIf
    Find String(DirSep) InString(lvFontFile) ReturnStatus(lvFound);
    If (not lvFound and lvFontFile not= '')
      Set lvFontFile = gvFontFolder +DirSep+ lvFontFile;
    EndIf
    Run ESys.ExtractPathName FileName(lvFontFile) NewVar(lvFolder);
    Get String FromString(lvFolder) NewVar(lvFolder)
      RemoveTrailing(DirSep);
    Run ESys.ExtractFileName FileName(lvFontFile) NewVar(lvFileName);
    Set gvData = gvData + lvFontName +CharLF+ lvFileName +
      CharLF+ lvFolder + CharLF;
  EndLoop
  EndSub

8< -------------------------------------------------


--- Original Message ---
From: Rick Quatro
Date: 04.08.2006 20:41
> Hello All,
> 
> This is from a client:
> 
> Recently they did something with our network. Now when I launch Frame it 
> takes a really long time to come up.
> It appears that it is hanging up when it gets to the fonts? Is there someone 
> I can go to check the path of where Frame is looking for fonts.
> Perhaps I need to remap. It eventually comes up but takes about 10 minutes.
> 
> Any help would be appreciated.
> 
> Rick Quatro
> Carmen Publishing
> 585-659-8267
> www.frameexpert.com